武相自由民権LOD

武相自由民権LODについて

三多摩地方を含む旧・神奈川県と埼玉県の自由民権運動における結社、人物、イベント、場所、地名をLinked Open Dataにして可視化しました。

インターネット上で閲覧できる文献に基づいてデータ化を進めています。

主な参考文献

RDF/XML形式のデータをGitHubで公開しています。SPARQLエンドポイントはこちらです。

データモデル

エンティティ間のリレーション

各エンティティで使用するプロパティ

プロパティ説明値の記述形式
rdf:typeこのエンティティの型schema:Organization
rdfs:labelラベル文字列
schema:name組織名文字列
schema:alternateName別名文字列
schema:parentOrganization上部組織schema:OrganizationのURI
schema:foundingDate設立日文字列（YYYY[-MM[-DD]]）
schema:dissolutionDate解散日文字列（YYYY[-MM[-DD]]）
schema:location本拠地schema:AdministrativeAreaのURI
schema:founder設立者、発起人、会主schema:PersonのURI
schema:organizer幹事、世話人、委員、主要人物schema:PersonのURI
schema:funder賛助員schema:PersonのURI
schema:member会員schema:PersonのURI
schema:sameAsウィキペディア、ウィキデータなどURI
dcterms:source情報源URI

プロパティ説明値の記述形式
rdf:typeこのエンティティの型schema:Person
rdfs:labelラベル文字列
schema:name氏名文字列
schema:alternateName別名文字列
schema:familyName姓文字列
schema:givenName名文字列
schema:gender性別schema:GenderTypeのURI
schema:birthDate生年月日文字列（YYYY[-MM[-DD]]）
schema:deathDate没年月日文字列（YYYY[-MM[-DD]]）
schema:parent親schema:PersonのURI
schema:children子schema:PersonのURI
schema:siblingきょうだいschema:PersonのURI
schema:birthPlace出生地schema:AdministrativeAreaのURI
schema:deathPlace死没地schema:AdministrativeAreaのURI
schema:homeLocation居住地schema:AdministrativeAreaのURI
schema:memberOf所属する結社（自由党または改進党）schema:OrganizationのURI
schema:sameAsウィキペディア、ウィキデータなどURI
dcterms:source情報源URI

プロパティ説明値の記述形式
rdf:typeこのエンティティの型schema:Event
rdfs:labelラベル文字列
schema:nameイベント名文字列
schema:organizer主催団体、主催者schema:Organizationまたはschema:PersonのURI
schema:performer講演者、演説者schema:PersonのURI
schema:attendee参加者schema:PersonのURI
schema:location開催地schema:Placeまたはschema:AdministrativeAreaのURI
schema:startDate開始日文字列（YYYY[-MM[-DD]]）
schema:endDate終了日文字列（YYYY[-MM[-DD]]）
schema:sameAsウィキペディア、ウィキデータなどURI
dcterms:source情報源URI

プロパティ説明値の記述形式
rdf:typeこのエンティティの型schema:Place
rdfs:labelラベル文字列
schema:name場所名文字列
schema:containedInPlaceこの場所を含む地名schema:AdministrativeAreaのURI
geo:lat緯度WGS84による10進表記の緯度
geo:long経度WGS84による10進表記の経度
schema:sameAsウィキペディア、ウィキデータなどURI
dcterms:source情報源URI

プロパティ説明値の記述形式
rdf:typeこのエンティティの型schema:AdministrativeArea
rdfs:labelラベル文字列
schema:name地名文字列
schema:containedInPlaceこの地域を含む地名schema:AdministrativeAreaのURI
geo:lat緯度WGS84による10進表記の緯度
geo:long経度WGS84による10進表記の経度
schema:sameAsウィキペディア、ウィキデータなどURI
dcterms:source情報源URI

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX schema: <https://schema.org/>

SPARQLを用いた検索と可視化の例

多くの結社の設立に参画した人物

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://schema.org/>
SELECT ?label COUNT(?group) AS ?value ?orgLabel WHERE {
  ?person rdf:type schema:Person.
  ?person rdfs:label ?label.
  OPTIONAL {
    ?person schema:memberOf ?org.
    ?org rdfs:label ?orgLabel.
  }
  ?group rdf:type schema:Organization.
  ?group ?p ?person.
  FILTER(?p = schema:founder || ?p = schema:organizer)
}
GROUP BY ?person
ORDER BY DESC(?value)
LIMIT 20

多くのイベントに参加した人物

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://schema.org/>
SELECT ?label COUNT(?event) AS ?value ?orgLabel WHERE {
  ?person rdf:type schema:Person.
  ?person rdfs:label ?label.
  OPTIONAL {
    ?person schema:memberOf ?org.
    ?org rdfs:label ?orgLabel.
  }
  ?event rdf:type schema:Event.
  ?event ?p ?person.
  FILTER(?p = schema:performer || ?p = schema:attendee)
}
GROUP BY ?person
ORDER BY DESC(?value) 
LIMIT 20

結社を設立した人物のつながり

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://schema.org/>
SELECT ?name1 ?orgLabel1 ?name2 ?orgLabel2 WHERE {
  ?group rdf:type schema:Organization.
  ?group schema:founder ?person1.
  ?person1 rdf:type schema:Person.
  ?person1 rdfs:label ?name1.
  OPTIONAL {
    ?person1 schema:memberOf ?org1.
    ?org1 rdfs:label ?orgLabel1.
  }
  ?group schema:founder ?person2.
  ?person2 rdf:type schema:Person.
  ?person2 rdfs:label ?name2.
  OPTIONAL {
    ?person2 schema:memberOf ?org2.
    ?org2 rdfs:label ?orgLabel2.
  }
  FILTER(?name1 > ?name2)
}

イベントで演説した人物のつながり

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://schema.org/>
SELECT ?name1 ?orgLabel1 ?name2 ?orgLabel2 WHERE {
  ?event rdf:type schema:Event.
  ?event schema:performer ?person1.
  ?person1 rdf:type schema:Person.
  ?person1 rdfs:label ?name1.
  OPTIONAL {
    ?person1 schema:memberOf ?org1.
    ?org1 rdfs:label ?orgLabel1.
  }
  ?event schema:performer ?person2.
  ?person2 rdf:type schema:Person.
  ?person2 rdfs:label ?name2.
  OPTIONAL {
    ?person2 schema:memberOf ?org2.
    ?org2 rdfs:label ?orgLabel2.
  }
  FILTER(?name1 > ?name2)
}

結社の本拠地

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX schema: <https://schema.org/>
SELECT ?s ?sLabel ?geoLabel ?lat ?long ?fDate {
  ?s rdf:type schema:Organization.
  ?s rdfs:label ?sLabel.
  ?s schema:location ?geo.
  ?geo rdfs:label ?geoLabel.
  ?geo geo:lat ?lat.
  ?geo geo:long ?long.
  ?s schema:foundingDate ?fDate.
}

人物の居住地と政党

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX schema: <https://schema.org/>
SELECT ?s ?sLabel ?geoLabel ?fDate ?lat ?long ?orgLabel {
  ?s rdf:type schema:Person.
  ?s rdfs:label ?sLabel.
  ?s schema:homeLocation ?geo.
  OPTIONAL {
    ?s schema:birthDate ?fDate.
  }
  ?geo rdfs:label ?geoLabel.
  ?geo geo:lat ?lat.
  ?geo geo:long ?long.
  OPTIONAL {
    ?s schema:memberOf ?org.
    ?org rdfs:label ?orgLabel.
  }
}

人物の居住地と結社本拠地・イベント開催地を結ぶ

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX schema: <https://schema.org/>
SELECT ?person ?pName ?pLocName ?orgLabel ?pLat ?pLon ?dst ?dstName ?locName ?dstLat ?dstLon ?dst2Lat ?dst2Lon WHERE {
  ?person rdf:type schema:Person.
  ?person rdfs:label ?pName.
  ?person schema:homeLocation ?pLoc.
  ?pLoc rdfs:label ?pLocName.
  ?pLoc geo:lat ?pLat.
  ?pLoc geo:long ?pLon.
  OPTIONAL {
    ?person schema:memberOf ?org.
    ?org rdfs:label ?orgLabel.
  }
  {
    ?dst rdf:type schema:Organization.
    ?dst ?p ?person.
    FILTER(?p=schema:founder || ?p=schema:organizer || ?p=schema:member)
    ?dst rdfs:label ?dstName.
    ?dst schema:location ?dstLoc.
    ?dstLoc rdfs:label ?locName.
    ?dstLoc geo:lat ?dstLat.
    ?dstLoc geo:long ?dstLon.
  } UNION {
    ?dst rdf:type schema:Event.
    ?dst ?p ?person.
    FILTER(?p=schema:organizer || ?p=schema:performer || ?p=schema:attendee)
    ?dst rdfs:label ?dstName.
    ?dst schema:location ?dstLoc.
    ?dstLoc rdfs:label ?locName.
    OPTIONAL {
      ?dstLoc geo:lat ?dstLat.
      ?dstLoc geo:long ?dstLon.
    }
    OPTIONAL {
      ?dstLoc schema:containedInPlace ?dst2.
      ?dst2 geo:lat ?dst2Lat.
      ?dst2 geo:long ?dst2Lon.
    }
  }
}

結社の設立時期

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://schema.org/>
SELECT ?org ?orgName ?foundingDate {
  ?org rdf:type schema:Organization.
  ?org rdfs:label ?orgName.
  ?org schema:foundingDate ?foundingDate.
}

主要な人物のライフスパン

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://schema.org/>
SELECT ?person ?name ?wiki ?birthDate ?deathDate ?orgLabel {
  ?person rdf:type schema:Person.
  ?person rdfs:label ?name.
  ?person schema:birthDate ?birthDate.
  ?person schema:deathDate ?deathDate.
  ?person schema:sameAs ?wiki.
  OPTIONAL {
    ?person schema:memberOf ?org.
    ?org rdfs:label ?orgLabel.
  }
  FILTER(regex(?wiki, "ja.wikipedia.org"))
}

石坂昌孝に関するすべての情報

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://schema.org/>
SELECT ?s ?sLabel ?p ?o ?oLabel WHERE {
  ?s ?p ?o.
  ?s rdfs:label ?sLabel.
  OPTIONAL {
    ?o rdfs:label ?oLabel.
  }
  FILTER (regex(?s, "P00001") || regex(?o, "P00001"))
}
ORDER BY DESC(?s)

当サイトは以下のオープンソースソフトウェアを利用しています。
クリエイティブ・コモンズ・ライセンス
この作品は クリエイティブ・コモンズ 表示 4.0 国際 ライセンスの下に提供されています。

Copyright © 2022 Midori IT, LLC.